Sparql query gebruiksfunctie

Datasets BAG
#1

Ik probeer een Sparql query uit te voeren op de Linked data BAG api, maar het lukt me niet echt om gebruiksdoelen op te halen van historische voorkomens.

Ik krijg in het resultaat alleen het huidige voorkomen en niet de historische voorkomen.

Mijn query

PREFIX bag: http://bag.basisregistraties.overheid.nl/def/bag#
PREFIX rdfs: http://www.w3.org/2000/01/rdf-schema#
PREFIX dct: http://purl.org/dc/terms/
PREFIX skos: http://www.w3.org/2004/02/skos/core#
PREFIX xsd: http://www.w3.org/2001/XMLSchema#
prefix rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#

select ?Verblijfsobject ?beginGeldigheid ?eindGeldigheid ?gebruiksdoel where {

graph ?verblijfsobjectVoorkomen
{
?Verblijfsobject
bag:identificatiecode “0003010000125996”;

}

?Verblijfsobject a ?type .
?type rdfs:subClassOf bag:Verblijfsobject ;
dct:subject / skos:notation ?gebruiksdoel .

?verblijfsobjectVoorkomen bag:beginGeldigheid ?beginGeldigheid

optional{
?verblijfsobjectVoorkomen bag:eindGeldigheid ?eindGeldigheid
}
}

het resultaat:

sparql resultaat
sparql resultaat1095×370 25.9 KB

Resultaat wat ik verwacht:

Sqlresult
Sqlresult850×150 17.4 KB

Weet iemand hoe ik de gebruiksfunctie kan ophalen bij de juiste begin en eindgeldigheid?

#2

Je dient het volgende triple pattern te verplaatsen naar het graph {} block erboven, omdat deze triple onderdeel uitmaakt van de voorkomen graph.

?Verblijfsobject a ?type .

#3

Je kan in principe alle eigenschappen van het voorkomen van het verblijfsobject uit de graph van het voorkomen halen (muv model informatie). De oplossing van @joostfarla werkt zeker, maar dit is een nettere query:

PREFIX bag: <http://bag.basisregistraties.overheid.nl/def/bag#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
select ?verblijfsobject ?gebruiksdoel ?beginGeldigheid ?eindGeldigheid where {
    graph ?voorkomen {
        ?verblijfsobject a ?type ;
                         bag:identificatiecode "0003010000125996".
        graph <http://bag.basisregistraties.overheid.nl/model> {
            ?type rdfs:subClassOf bag:Verblijfsobject ;
                  dct:subject / skos:notation ?gebruiksdoel .
        }
        ?voorkomen bag:beginGeldigheid ?beginGeldigheid
        optional{
            ?voorkomen bag:eindGeldigheid ?eindGeldigheid
        }
    }
}
#4

Super. Dit is precies wat ik zoek!

Bedankt